cmake_minimum_required(VERSION 3.5)
project(tutorial_opencv)
# Default to C99
if(NOT CMAKE_C_STANDARD)
  set(CMAKE_C_STANDARD 99)
endif()
# Default to C++14
if(NOT CMAKE_CXX_STANDARD)
  set(CMAKE_CXX_STANDARD 14)
endif()
# Add compile options
if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  add_compile_options(-Wall -Wextra -Wpedantic)
endif()
# Find dependencies
find_package(ament_cmake REQUIRED)
find_package(rclcpp REQUIRED)
find_package(OpenCV REQUIRED COMPONENTS core highgui videoio)
find_package(cv_bridge REQUIRED)
find_package(sensor_msgs REQUIRED)
find_package(rclcpp_components REQUIRED)
# Set target
set(NODES color2gray;image_publisher;image_subscriber)
foreach(target IN LISTS NODES)
  add_executable(${target} src/${target}.cpp)
  ament_target_dependencies(${target} rclcpp OpenCV cv_bridge sensor_msgs)
  install(TARGETS ${target} DESTINATION lib/${PROJECT_NAME})
endforeach()
add_library(${PROJECT_NAME} SHARED
  src/image_publisher_component.cpp
  src/image_subscriber_component.cpp
)
ament_target_dependencies(${PROJECT_NAME} rclcpp OpenCV cv_bridge sensor_msgs rclcpp_components)
rclcpp_components_register_nodes(${PROJECT_NAME} "tutorial_opencv::ImagePublisher")
rclcpp_components_register_nodes(${PROJECT_NAME} "tutorial_opencv::ImageSubscriber")
install(TARGETS ${PROJECT_NAME} DESTINATION lib)
# Call ament build system
ament_package()